AutoHotKey 스크립트 공유

스크립트에 대한 설명:

Mouse Wheel과 Mouse Middle Button을 가지고
Master Volume을 조작하는 Script입니다.
( 몇몇 Windows에서는 동작을 안 할 수도 있습니다. )

사용 방법:

1. Mouse Wheel
Window Titlebar위에서 Mouse Wheel을 위로
올리면 Volume이 10%씩 올라가고
Mouse Wheel을 내리게 되면 10%씩 감소합니다.

2. Mouse Middle Button
Window Titlebar를 3등분으로 나누어
왼쪽을 Click하게 되면 Volume 이 0%로
가운데를 Click하게 되면 Volume 이 50%로
오른쪽을 Click하게 되면 Volume 이 100%로
그리고 오른쪽의 3개의 버튼( 최소화, 복원, 닫기 )
을 Click하게 되면 Mute가 Toggle 됩니다.

***Windows Vista와 Windows 7 사용자 Tip***
이 Script는 위의 두 OS에서는 작동을 하지 않습니다.
위의 OS에서 Script를 사용하시려면,
AutoHotkey.exe 파일의 속성을 Windows XP
호환 모드로 바꾸시면 됩니다.

<--------------------------------------------- AHK 스크립트 내용 --------------------------------------------->

/*
TitleBar Volume Control

Script By NewJung
*/

CoordMode, Mouse, Screen
SetTimer, Volume_Progress, 3000
Return

Volume_Progress:
Progress, Off
Return

WhatIsUnderMouse(  )  ;;;;;;;;;;;;;;;;;;;;;;;; Get The Control Info
{
  Global Title,WW,WH,Low,Mid,High
  MouseGetPos, X, Y
  WinGetActiveTitle, Title
  WinGetPos, DummyX,DummyY,WW,WH, %Title%
  SendMessage, 0x84, , ( Y << 16 ) | X , , %Title%
  Low := WW // 3
  Mid := Low * 2
  High := WW
  Return ErrorLevel
}

Sound(SLevel)  ;;;;;;;;;;;;;;;;;;;;;;;; Volume Level Control Function
{
  If ( SLevel = "Mute" )
    SoundSet, +1, , Mute
  Else
    SoundSet %SLevel%
  SoundGet, Mas_Sound
  SoundGet, Mute,,Mute
  If ( Mute = "On" )
    Master_Volume = Master Volume Muted!
  Else
  {
    Mas_Sound := Round(Mas_Sound)
    Master_Volume = Master Volume %Mas_Sound%`%
  }
  Progress, b w500 fm28, ,%Master_Volume%
  Progress, %Mas_Sound%
  Settimer, Volume_Progress, Off  ;;;;;;;;;;;;;;;;;;;;;;;; Refresh SetTimer
  Settimer, Volume_Progress, On
  Return
}

WheelUp::  ;;;;;;;;;;;;;;;;;;;;;;;; Master Volume Increase By 10%
Result := WhatIsUnderMouse( )
If Result Contains 2,3,8,9,20
  Sound( "+10" )
Else
 Send {WheelUp}
Return

WheelDown::  ;;;;;;;;;;;;;;;;;;;;;;;; Master Volume Decrease By 10%
Result := WhatIsUnderMouse( )
If Result Contains 2,3,8,9,20
  Sound( "-10" )
Else
 Send {WheelDown}
Return

~MButton::
Result := WhatIsUnderMouse( )
CoordMode, Mouse, Relative
MouseGetPos, XX, YY
If ( Result = 2 and XX > 0 and XX < Low )  ;;;;;;;;;;;;;;;;;;;;;;;; Set Master Volume To 0%
  Sound( "0" )
Else If ( Result = 2 and XX > Low and XX < Mid )  ;;;;;;;;;;;;;;;;;;;;;;;; Set Master Volume To 50%
  Sound( "50" )
Else If ( Result = 2 and XX > Mid and XX < High )  ;;;;;;;;;;;;;;;;;;;;;;;; Set Master Volume To 100%
  Sound( "100" )
Else If Result Contains 8,9,20  ;;;;;;;;;;;;;;;;;;;;;;;; Mute Toggle
  Sound( "Mute" )
Return